summaryrefslogtreecommitdiff
path: root/Webduino/examples
diff options
context:
space:
mode:
Diffstat (limited to 'Webduino/examples')
-rw-r--r--Webduino/examples/Web_AjaxBuzzer/Web_AjaxBuzzer.ino126
-rw-r--r--Webduino/examples/Web_AjaxRGB/Web_AjaxRGB.ino142
-rw-r--r--Webduino/examples/Web_AjaxRGB_mobile/Web_AjaxRGB_mobile.ino140
-rw-r--r--Webduino/examples/Web_Authentication/Web_Authentication.ino106
-rw-r--r--Webduino/examples/Web_Buzzer/Web_Buzzer.ino123
-rw-r--r--Webduino/examples/Web_Demo/Web_Demo.ino189
-rw-r--r--Webduino/examples/Web_HelloWorld/Web_HelloWorld.ino71
-rw-r--r--Webduino/examples/Web_Image/Web_Image.ino117
-rw-r--r--Webduino/examples/Web_Image/led.pngbin0 -> 253 bytes
-rw-r--r--Webduino/examples/Web_Parms/Web_Parms.ino287
10 files changed, 1301 insertions, 0 deletions
diff --git a/Webduino/examples/Web_AjaxBuzzer/Web_AjaxBuzzer.ino b/Webduino/examples/Web_AjaxBuzzer/Web_AjaxBuzzer.ino
new file mode 100644
index 0000000..e546030
--- /dev/null
+++ b/Webduino/examples/Web_AjaxBuzzer/Web_AjaxBuzzer.ino
@@ -0,0 +1,126 @@
+/* Web_Buzzer.pde - example sketch for Webduino library */
+
+#include "SPI.h"
+#include "Ethernet.h"
+#include "WebServer.h"
+
+// CHANGE THIS TO YOUR OWN UNIQUE VALUE
+static uint8_t mac[6] = { 0x02, 0xAA, 0xBB, 0xCC, 0x00, 0x22 };
+
+// CHANGE THIS TO MATCH YOUR HOST NETWORK
+static uint8_t ip[4] = { 192, 168, 1, 210 }; // area 51!
+
+/* all URLs on this server will start with /buzz because of how we
+ * define the PREFIX value. We also will listen on port 80, the
+ * standard HTTP service port */
+#define PREFIX "/buzz"
+WebServer webserver(PREFIX, 80);
+
+/* the piezo speaker on the Danger Shield is on PWM output pin #3 */
+#define BUZZER_PIN 3
+
+/* this is the number of microseconds to wait after turning the
+ * speaker on before turning it off. */
+int buzzDelay = 0;
+
+/* toggle is used to only turn on the speaker every other loop
+iteration. */
+char toggle = 0;
+
+/* This command is set as the default command for the server. It
+ * handles both GET and POST requests. For a GET, it returns a simple
+ * page with some buttons. For a POST, it saves the value posted to
+ * the buzzDelay variable, affecting the output of the speaker */
+void buzzCmd(WebServer &server, WebServer::ConnectionType type, char *, bool)
+{
+ if (type == WebServer::POST)
+ {
+ bool repeat;
+ char name[16], value[16];
+ do
+ {
+ /* readPOSTparam returns false when there are no more parameters
+ * to read from the input. We pass in buffers for it to store
+ * the name and value strings along with the length of those
+ * buffers. */
+ repeat = server.readPOSTparam(name, 16, value, 16);
+
+ /* this is a standard string comparison function. It returns 0
+ * when there's an exact match. We're looking for a parameter
+ * named "buzz" here. */
+ if (strcmp(name, "buzz") == 0)
+ {
+ /* use the STRing TO Unsigned Long function to turn the string
+ * version of the delay number into our integer buzzDelay
+ * variable */
+ buzzDelay = strtoul(value, NULL, 10);
+ }
+ } while (repeat);
+
+ // after procesing the POST data, tell the web browser to reload
+ // the page using a GET method.
+ server.httpSeeOther(PREFIX);
+ return;
+ }
+
+ /* for a GET or HEAD, send the standard "it's all OK headers" */
+ server.httpSuccess();
+
+ /* we don't output the body for a HEAD request */
+ if (type == WebServer::GET)
+ {
+ /* store the HTML in program memory using the P macro */
+ P(message) =
+"<!DOCTYPE html><html><head>"
+ "<title>Webduino AJAX Buzzer Example</title>"
+ "<link href='http://ajax.googleapis.com/ajax/libs/jqueryui/1.8.16/themes/base/jquery-ui.css' rel=stylesheet />"
+ //"<meta http-equiv='Content-Script-Type' content='text/javascript'>"
+ "<script src='http://ajax.googleapis.com/ajax/libs/jquery/1.6.4/jquery.min.js'></script>"
+ "<script src='http://ajax.googleapis.com/ajax/libs/jqueryui/1.8.16/jquery-ui.min.js'></script>"
+ "<style> #slider { margin: 10px; } </style>"
+ "<script>"
+ "function changeBuzz(event, ui) { $('#indicator').text(ui.value); $.post('/buzz', { buzz: ui.value } ); }"
+ "$(document).ready(function(){ $('#slider').slider({min: 0, max:8000, change:changeBuzz}); });"
+ "</script>"
+"</head>"
+"<body style='font-size:62.5%;'>"
+ "<h1>Test the Buzzer!</h1>"
+ "<div id=slider></div>"
+ "<p id=indicator>0</p>"
+"</body>"
+"</html>";
+
+ server.printP(message);
+ }
+}
+
+void setup()
+{
+ // set the PWM output for the buzzer to out
+ pinMode(BUZZER_PIN, OUTPUT);
+
+ // setup the Ehternet library to talk to the Wiznet board
+ Ethernet.begin(mac, ip);
+
+ /* register our default command (activated with the request of
+ * http://x.x.x.x/buzz */
+ webserver.setDefaultCommand(&buzzCmd);
+
+ /* start the server to wait for connections */
+ webserver.begin();
+}
+
+void loop()
+{
+ // process incoming connections one at a time forever
+ webserver.processConnection();
+
+ /* every other time through the loop, turn on and off the speaker if
+ * our delay isn't set to 0. */
+ if ((++toggle & 1) && (buzzDelay > 0))
+ {
+ digitalWrite(BUZZER_PIN, HIGH);
+ delayMicroseconds(buzzDelay);
+ digitalWrite(BUZZER_PIN, LOW);
+ }
+}
diff --git a/Webduino/examples/Web_AjaxRGB/Web_AjaxRGB.ino b/Webduino/examples/Web_AjaxRGB/Web_AjaxRGB.ino
new file mode 100644
index 0000000..8e05a8c
--- /dev/null
+++ b/Webduino/examples/Web_AjaxRGB/Web_AjaxRGB.ino
@@ -0,0 +1,142 @@
+/* Web_AjaxRGB.pde - example sketch for Webduino library */
+
+#include "SPI.h"
+#include "Ethernet.h"
+#include "WebServer.h"
+
+// CHANGE THIS TO YOUR OWN UNIQUE VALUE
+static uint8_t mac[6] = { 0x02, 0xAA, 0xBB, 0xCC, 0x00, 0x22 };
+
+// CHANGE THIS TO MATCH YOUR HOST NETWORK
+static uint8_t ip[4] = { 192, 168, 1, 210 }; // area 51!
+
+/* all URLs on this server will start with /rgb because of how we
+ * define the PREFIX value. We also will listen on port 80, the
+ * standard HTTP service port */
+#define PREFIX "/rgb"
+WebServer webserver(PREFIX, 80);
+
+#define RED_PIN 5
+#define GREEN_PIN 3
+#define BLUE_PIN 6
+
+int red = 0; //integer for red darkness
+int blue = 0; //integer for blue darkness
+int green = 0; //integer for green darkness
+
+/* This command is set as the default command for the server. It
+ * handles both GET and POST requests. For a GET, it returns a simple
+ * page with some buttons. For a POST, it saves the value posted to
+ * the red/green/blue variable, affecting the output of the speaker */
+void rgbCmd(WebServer &server, WebServer::ConnectionType type, char *, bool)
+{
+ if (type == WebServer::POST)
+ {
+ bool repeat;
+ char name[16], value[16];
+ do
+ {
+ /* readPOSTparam returns false when there are no more parameters
+ * to read from the input. We pass in buffers for it to store
+ * the name and value strings along with the length of those
+ * buffers. */
+ repeat = server.readPOSTparam(name, 16, value, 16);
+
+ /* this is a standard string comparison function. It returns 0
+ * when there's an exact match. We're looking for a parameter
+ * named red/green/blue here. */
+ if (strcmp(name, "red") == 0)
+ {
+ /* use the STRing TO Unsigned Long function to turn the string
+ * version of the color strength value into our integer red/green/blue
+ * variable */
+ red = strtoul(value, NULL, 10);
+ }
+ if (strcmp(name, "green") == 0)
+ {
+ green = strtoul(value, NULL, 10);
+ }
+ if (strcmp(name, "blue") == 0)
+ {
+ blue = strtoul(value, NULL, 10);
+ }
+ } while (repeat);
+
+ // after procesing the POST data, tell the web browser to reload
+ // the page using a GET method.
+ server.httpSeeOther(PREFIX);
+// Serial.print(name);
+// Serial.println(value);
+
+ return;
+ }
+
+ /* for a GET or HEAD, send the standard "it's all OK headers" */
+ server.httpSuccess();
+
+ /* we don't output the body for a HEAD request */
+ if (type == WebServer::GET)
+ {
+ /* store the HTML in program memory using the P macro */
+ P(message) =
+"<!DOCTYPE html><html><head>"
+ "<title>Webduino AJAX RGB Example</title>"
+ "<link href='http://ajax.googleapis.com/ajax/libs/jqueryui/1.8.16/themes/base/jquery-ui.css' rel=stylesheet />"
+ "<script src='http://ajax.googleapis.com/ajax/libs/jquery/1.6.4/jquery.min.js'></script>"
+ "<script src='http://ajax.googleapis.com/ajax/libs/jqueryui/1.8.16/jquery-ui.min.js'></script>"
+ "<style> body { background: black; } #red, #green, #blue { margin: 10px; } #red { background: #f00; } #green { background: #0f0; } #blue { background: #00f; } </style>"
+ "<script>"
+
+// change color on mouse up, not while sliding (causes much less traffic to the Arduino):
+// "function changeRGB(event, ui) { var id = $(this).attr('id'); if (id == 'red') $.post('/rgb', { red: ui.value } ); if (id == 'green') $.post('/rgb', { green: ui.value } ); if (id == 'blue') $.post('/rgb', { blue: ui.value } ); } "
+// "$(document).ready(function(){ $('#red, #green, #blue').slider({min: 0, max:255, change:changeRGB}); });"
+
+// change color on slide and mouse up (causes more traffic to the Arduino):
+ "function changeRGB(event, ui) { jQuery.ajaxSetup({timeout: 110}); /*not to DDoS the Arduino, you might have to change this to some threshold value that fits your setup*/ var id = $(this).attr('id'); if (id == 'red') $.post('/rgb', { red: ui.value } ); if (id == 'green') $.post('/rgb', { green: ui.value } ); if (id == 'blue') $.post('/rgb', { blue: ui.value } ); } "
+ "$(document).ready(function(){ $('#red, #green, #blue').slider({min: 0, max:255, change:changeRGB, slide:changeRGB}); });"
+
+ "</script>"
+"</head>"
+"<body style='font-size:62.5%;'>"
+ "<div id=red></div>"
+ "<div id=green></div>"
+ "<div id=blue></div>"
+"</body>"
+"</html>";
+
+ server.printP(message);
+ }
+}
+
+void setup()
+{
+ pinMode(RED_PIN, OUTPUT);
+ pinMode(GREEN_PIN, OUTPUT);
+ pinMode(BLUE_PIN, OUTPUT);
+
+// Serial.begin(9600);
+
+ // setup the Ehternet library to talk to the Wiznet board
+ Ethernet.begin(mac, ip);
+
+ /* register our default command (activated with the request of
+ * http://x.x.x.x/rgb */
+ webserver.setDefaultCommand(&rgbCmd);
+
+ /* start the server to wait for connections */
+ webserver.begin();
+}
+
+void loop()
+{
+ // process incoming connections one at a time forever
+ webserver.processConnection();
+// Serial.print(red);
+// Serial.print(" ");
+// Serial.print(green);
+// Serial.print(" ");
+// Serial.println(blue);
+ analogWrite(RED_PIN, red);
+ analogWrite(GREEN_PIN, green);
+ analogWrite(BLUE_PIN, blue);
+}
diff --git a/Webduino/examples/Web_AjaxRGB_mobile/Web_AjaxRGB_mobile.ino b/Webduino/examples/Web_AjaxRGB_mobile/Web_AjaxRGB_mobile.ino
new file mode 100644
index 0000000..aa49ee2
--- /dev/null
+++ b/Webduino/examples/Web_AjaxRGB_mobile/Web_AjaxRGB_mobile.ino
@@ -0,0 +1,140 @@
+/* Web_AjaxRGB_mobile.pde - example sketch for Webduino library */
+/* - offers web-based slider controllers for RGB led - */
+
+#include "SPI.h"
+#include "Ethernet.h"
+#include "WebServer.h"
+
+// CHANGE THIS TO YOUR OWN UNIQUE VALUE
+static uint8_t mac[6] = { 0x02, 0xAA, 0xBB, 0xCC, 0x00, 0x22 };
+
+// CHANGE THIS TO MATCH YOUR HOST NETWORK
+static uint8_t ip[4] = { 192, 168, 1, 210 }; // area 51!
+
+/* all URLs on this server will start with /rgb because of how we
+ * define the PREFIX value. We also will listen on port 80, the
+ * standard HTTP service port */
+#define PREFIX "/rgb"
+WebServer webserver(PREFIX, 80);
+
+#define RED_PIN 5
+#define GREEN_PIN 3
+#define BLUE_PIN 6
+
+int red = 0; //integer for red darkness
+int blue = 0; //integer for blue darkness
+int green = 0; //integer for green darkness
+
+/* This command is set as the default command for the server. It
+ * handles both GET and POST requests. For a GET, it returns a simple
+ * page with some buttons. For a POST, it saves the value posted to
+ * the red/green/blue variable, affecting the output of the speaker */
+void rgbCmd(WebServer &server, WebServer::ConnectionType type, char *, bool)
+{
+ if (type == WebServer::POST)
+ {
+ bool repeat;
+ char name[16], value[16];
+ do
+ {
+ /* readPOSTparam returns false when there are no more parameters
+ * to read from the input. We pass in buffers for it to store
+ * the name and value strings along with the length of those
+ * buffers. */
+ repeat = server.readPOSTparam(name, 16, value, 16);
+
+ /* this is a standard string comparison function. It returns 0
+ * when there's an exact match. We're looking for a parameter
+ * named red/green/blue here. */
+ if (strcmp(name, "red") == 0)
+ {
+ /* use the STRing TO Unsigned Long function to turn the string
+ * version of the color strength value into our integer red/green/blue
+ * variable */
+ red = strtoul(value, NULL, 10);
+ }
+ if (strcmp(name, "green") == 0)
+ {
+ green = strtoul(value, NULL, 10);
+ }
+ if (strcmp(name, "blue") == 0)
+ {
+ blue = strtoul(value, NULL, 10);
+ }
+ } while (repeat);
+
+ // after procesing the POST data, tell the web browser to reload
+ // the page using a GET method.
+ server.httpSeeOther(PREFIX);
+// Serial.print(name);
+// Serial.println(value);
+
+ return;
+ }
+
+ /* for a GET or HEAD, send the standard "it's all OK headers" */
+ server.httpSuccess();
+
+ /* we don't output the body for a HEAD request */
+ if (type == WebServer::GET)
+ {
+ /* store the HTML in program memory using the P macro */
+ P(message) =
+"<!DOCTYPE html><html><head>"
+ "<meta charset=\"utf-8\"><meta name=\"apple-mobile-web-app-capable\" content=\"yes\" /><meta http-equiv=\"X-UA-Compatible\" content=\"IE=edge,chrome=1\"><meta name=\"viewport\" content=\"width=device-width, user-scalable=no\">"
+ "<title>Webduino RGB</title>"
+ "<link rel=\"stylesheet\" href=\"http://code.jquery.com/mobile/1.0/jquery.mobile-1.0.min.css\" />"
+ "<script src=\"http://code.jquery.com/jquery-1.6.4.min.js\"></script>"
+ "<script src=\"http://code.jquery.com/mobile/1.0/jquery.mobile-1.0.min.js\"></script>"
+ "<style> body, .ui-page { background: black; } .ui-body { padding-bottom: 1.5em; } div.ui-slider { width: 88%; } #red, #green, #blue { display: block; margin: 10px; } #red { background: #f00; } #green { background: #0f0; } #blue { background: #00f; } </style>"
+ "<script>"
+// causes the Arduino to hang quite frequently (more often than Web_AjaxRGB.pde), probably due to the different event triggering the ajax requests
+ "$(document).ready(function(){ $('#red, #green, #blue').slider; $('#red, #green, #blue').bind( 'change', function(event, ui) { jQuery.ajaxSetup({timeout: 110}); /*not to DDoS the Arduino, you might have to change this to some threshold value that fits your setup*/ var id = $(this).attr('id'); var strength = $(this).val(); if (id == 'red') $.post('/rgb', { red: strength } ); if (id == 'green') $.post('/rgb', { green: strength } ); if (id == 'blue') $.post('/rgb', { blue: strength } ); });});"
+ "</script>"
+"</head>"
+"<body>"
+ "<div data-role=\"header\" data-position=\"inline\"><h1>Webduino RGB</h1></div>"
+ "<div class=\"ui-body ui-body-a\">"
+ "<input type=\"range\" name=\"slider\" id=\"red\" value=\"0\" min=\"0\" max=\"255\" />"
+ "<input type=\"range\" name=\"slider\" id=\"green\" value=\"0\" min=\"0\" max=\"255\" />"
+ "<input type=\"range\" name=\"slider\" id=\"blue\" value=\"0\" min=\"0\" max=\"255\" />"
+ "</div>"
+ "</body>"
+"</html>";
+
+ server.printP(message);
+ }
+}
+
+void setup()
+{
+ pinMode(RED_PIN, OUTPUT);
+ pinMode(GREEN_PIN, OUTPUT);
+ pinMode(BLUE_PIN, OUTPUT);
+
+// Serial.begin(9600);
+
+ // setup the Ehternet library to talk to the Wiznet board
+ Ethernet.begin(mac, ip);
+
+ /* register our default command (activated with the request of
+ * http://x.x.x.x/rgb */
+ webserver.setDefaultCommand(&rgbCmd);
+
+ /* start the server to wait for connections */
+ webserver.begin();
+}
+
+void loop()
+{
+ // process incoming connections one at a time forever
+ webserver.processConnection();
+// Serial.print(red);
+// Serial.print(" ");
+// Serial.print(green);
+// Serial.print(" ");
+// Serial.println(blue);
+ analogWrite(RED_PIN, red);
+ analogWrite(GREEN_PIN, green);
+ analogWrite(BLUE_PIN, blue);
+}
diff --git a/Webduino/examples/Web_Authentication/Web_Authentication.ino b/Webduino/examples/Web_Authentication/Web_Authentication.ino
new file mode 100644
index 0000000..4a2384d
--- /dev/null
+++ b/Webduino/examples/Web_Authentication/Web_Authentication.ino
@@ -0,0 +1,106 @@
+/* Web_Authentication.ino - Webduino Authentication example */
+
+/* This example assumes that you're familiar with the basics
+ * of the Ethernet library (particularly with setting MAC and
+ * IP addresses) and with the basics of Webduino. If you
+ * haven't had a look at the HelloWorld example you should
+ * probably check it out first */
+
+/* you can change the authentication realm by defining
+ * WEBDUINO_AUTH_REALM before including WebServer.h */
+#define WEBDUINO_AUTH_REALM "Weduino Authentication Example"
+
+#include "SPI.h"
+#include "Ethernet.h"
+#include "WebServer.h"
+
+/* CHANGE THIS TO YOUR OWN UNIQUE VALUE. The MAC number should be
+ * different from any other devices on your network or you'll have
+ * problems receiving packets. */
+static uint8_t mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
+
+/* CHANGE THIS TO MATCH YOUR HOST NETWORK. Most home networks are in
+ * the 192.168.0.XXX or 192.168.1.XXX subrange. Pick an address
+ * that's not in use and isn't going to be automatically allocated by
+ * DHCP from your router. */
+static uint8_t ip[] = { 192, 168, 1, 210 };
+
+/* This creates an instance of the webserver. By specifying a prefix
+ * of "", all pages will be at the root of the server. */
+#define PREFIX ""
+WebServer webserver(PREFIX, 80);
+
+void defaultCmd(WebServer &server, WebServer::ConnectionType type, char *, bool)
+{
+ server.httpSuccess();
+ if (type != WebServer::HEAD)
+ {
+ P(helloMsg) = "<h1>Hello, World!</h1><a href=\"private.html\">Private page</a>";
+ server.printP(helloMsg);
+ }
+}
+
+void privateCmd(WebServer &server, WebServer::ConnectionType type, char *, bool)
+{
+ /* if the user has requested this page using the following credentials
+ * username = user
+ * password = user
+ * display a page saying "Hello User"
+ *
+ * the credentials have to be concatenated with a colon like
+ * username:password
+ * and encoded using Base64 - this should be done outside of your Arduino
+ * to be easy on your resources
+ *
+ * in other words: "dXNlcjp1c2Vy" is the Base64 representation of "user:user"
+ *
+ * if you need to change the username/password dynamically please search
+ * the web for a Base64 library */
+ if (server.checkCredentials("dXNlcjp1c2Vy"))
+ {
+ server.httpSuccess();
+ if (type != WebServer::HEAD)
+ {
+ P(helloMsg) = "<h1>Hello User</h1>";
+ server.printP(helloMsg);
+ }
+ }
+ /* if the user has requested this page using the following credentials
+ * username = admin
+ * password = admin
+ * display a page saying "Hello Admin"
+ *
+ * in other words: "YWRtaW46YWRtaW4=" is the Base64 representation of "admin:admin" */
+ else if (server.checkCredentials("YWRtaW46YWRtaW4="))
+ {
+ server.httpSuccess();
+ if (type != WebServer::HEAD)
+ {
+ P(helloMsg) = "<h1>Hello Admin</h1>";
+ server.printP(helloMsg);
+ }
+ }
+ else
+ {
+ /* send a 401 error back causing the web browser to prompt the user for credentials */
+ server.httpUnauthorized();
+ }
+}
+
+void setup()
+{
+ Ethernet.begin(mac, ip);
+ webserver.setDefaultCommand(&defaultCmd);
+ webserver.addCommand("index.html", &defaultCmd);
+ webserver.addCommand("private.html", &privateCmd);
+ webserver.begin();
+}
+
+void loop()
+{
+ char buff[64];
+ int len = 64;
+
+ /* process incoming connections one at a time forever */
+ webserver.processConnection(buff, &len);
+}
diff --git a/Webduino/examples/Web_Buzzer/Web_Buzzer.ino b/Webduino/examples/Web_Buzzer/Web_Buzzer.ino
new file mode 100644
index 0000000..083f315
--- /dev/null
+++ b/Webduino/examples/Web_Buzzer/Web_Buzzer.ino
@@ -0,0 +1,123 @@
+/* Web_Buzzer.pde - example sketch for Webduino library */
+
+#include "SPI.h"
+#include "Ethernet.h"
+#include "WebServer.h"
+
+/* CHANGE THIS TO YOUR OWN UNIQUE VALUE. The MAC number should be
+ * different from any other devices on your network or you'll have
+ * problems receiving packets. */
+static uint8_t mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
+
+/* CHANGE THIS TO MATCH YOUR HOST NETWORK. Most home networks are in
+ * the 192.168.0.XXX or 192.168.1.XXX subrange. Pick an address
+ * that's not in use and isn't going to be automatically allocated by
+ * DHCP from your router. */
+static uint8_t ip[] = { 192, 168, 1, 210 };
+
+/* all URLs on this server will start with /buzz because of how we
+ * define the PREFIX value. We also will listen on port 80, the
+ * standard HTTP service port */
+#define PREFIX "/buzz"
+WebServer webserver(PREFIX, 80);
+
+/* the piezo speaker on the Danger Shield is on PWM output pin #3 */
+#define BUZZER_PIN 3
+
+/* this is the number of microseconds to wait after turning the
+ * speaker on before turning it off. */
+int buzzDelay = 0;
+
+/* toggle is used to only turn on the speaker every other loop
+iteration. */
+char toggle = 0;
+
+/* This command is set as the default command for the server. It
+ * handles both GET and POST requests. For a GET, it returns a simple
+ * page with some buttons. For a POST, it saves the value posted to
+ * the buzzDelay variable, affecting the output of the speaker */
+void buzzCmd(WebServer &server, WebServer::ConnectionType type, char *url_tail, bool tail_complete)
+{
+ if (type == WebServer::POST)
+ {
+ bool repeat;
+ char name[16], value[16];
+ do
+ {
+ /* readPOSTparam returns false when there are no more parameters
+ * to read from the input. We pass in buffers for it to store
+ * the name and value strings along with the length of those
+ * buffers. */
+ repeat = server.readPOSTparam(name, 16, value, 16);
+
+ /* this is a standard string comparison function. It returns 0
+ * when there's an exact match. We're looking for a parameter
+ * named "buzz" here. */
+ if (strcmp(name, "buzz") == 0)
+ {
+ /* use the STRing TO Unsigned Long function to turn the string
+ * version of the delay number into our integer buzzDelay
+ * variable */
+ buzzDelay = strtoul(value, NULL, 10);
+ }
+ } while (repeat);
+
+ // after procesing the POST data, tell the web browser to reload
+ // the page using a GET method.
+ server.httpSeeOther(PREFIX);
+ return;
+ }
+
+ /* for a GET or HEAD, send the standard "it's all OK headers" */
+ server.httpSuccess();
+
+ /* we don't output the body for a HEAD request */
+ if (type == WebServer::GET)
+ {
+ /* store the HTML in program memory using the P macro */
+ P(message) =
+ "<html><head><title>Webduino Buzzer Example</title>"
+ "<body>"
+ "<h1>Test the Buzzer!</h1>"
+ "<form action='/buzz' method='POST'>"
+ "<p><button name='buzz' value='0'>Turn if Off!</button></p>"
+ "<p><button name='buzz' value='500'>500</button></p>"
+ "<p><button name='buzz' value='1975'>1975</button></p>"
+ "<p><button name='buzz' value='3000'>3000</button></p>"
+ "<p><button name='buzz' value='8000'>8000</button></p>"
+ "</form></body></html>";
+
+ server.printP(message);
+ }
+}
+
+void setup()
+{
+ // set the PWM output for the buzzer to out
+ pinMode(BUZZER_PIN, OUTPUT);
+
+ // setup the Ehternet library to talk to the Wiznet board
+ Ethernet.begin(mac, ip);
+
+ /* register our default command (activated with the request of
+ * http://x.x.x.x/buzz */
+ webserver.setDefaultCommand(&buzzCmd);
+
+ /* start the server to wait for connections */
+ webserver.begin();
+}
+
+void loop()
+{
+ // process incoming connections one at a time forever
+ webserver.processConnection();
+
+ /* every other time through the loop, turn on and off the speaker if
+ * our delay isn't set to 0. */
+ if ((++toggle & 1) && (buzzDelay > 0))
+ {
+ digitalWrite(BUZZER_PIN, HIGH);
+ delayMicroseconds(buzzDelay);
+ digitalWrite(BUZZER_PIN, LOW);
+ }
+}
diff --git a/Webduino/examples/Web_Demo/Web_Demo.ino b/Webduino/examples/Web_Demo/Web_Demo.ino
new file mode 100644
index 0000000..bb4a016
--- /dev/null
+++ b/Webduino/examples/Web_Demo/Web_Demo.ino
@@ -0,0 +1,189 @@
+/* Web_Demo.pde -- sample code for Webduino server library */
+
+/*
+ * To use this demo, enter one of the following USLs into your browser.
+ * Replace "host" with the IP address assigned to the Arduino.
+ *
+ * http://host/
+ * http://host/json
+ *
+ * This URL brings up a display of the values READ on digital pins 0-9
+ * and analog pins 0-5. This is done with a call to defaultCmd.
+ *
+ *
+ * http://host/form
+ *
+ * This URL also brings up a display of the values READ on digital pins 0-9
+ * and analog pins 0-5. But it's done as a form, by the "formCmd" function,
+ * and the digital pins are shown as radio buttons you can change.
+ * When you click the "Submit" button, it does a POST that sets the
+ * digital pins, re-reads them, and re-displays the form.
+ *
+ */
+
+#include "SPI.h"
+#include "Ethernet.h"
+#include "WebServer.h"
+
+// no-cost stream operator as described at
+// http://sundial.org/arduino/?page_id=119
+template<class T>
+inline Print &operator <<(Print &obj, T arg)
+{ obj.print(arg); return obj; }
+
+
+// CHANGE THIS TO YOUR OWN UNIQUE VALUE
+static uint8_t mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
+
+// CHANGE THIS TO MATCH YOUR HOST NETWORK
+static uint8_t ip[] = { 192, 168, 1, 210 };
+
+#define PREFIX ""
+
+WebServer webserver(PREFIX, 80);
+
+// commands are functions that get called by the webserver framework
+// they can read any posted data from client, and they output to server
+
+void jsonCmd(WebServer &server, WebServer::ConnectionType type, char *url_tail, bool tail_complete)
+{
+ if (type == WebServer::POST)
+ {
+ server.httpFail();
+ return;
+ }
+
+ //server.httpSuccess(false, "application/json");
+ server.httpSuccess("application/json");
+
+ if (type == WebServer::HEAD)
+ return;
+
+ int i;
+ server << "{ ";
+ for (i = 0; i <= 9; ++i)
+ {
+ // ignore the pins we use to talk to the Ethernet chip
+ int val = digitalRead(i);
+ server << "\"d" << i << "\": " << val << ", ";
+ }
+
+ for (i = 0; i <= 5; ++i)
+ {
+ int val = analogRead(i);
+ server << "\"a" << i << "\": " << val;
+ if (i != 5)
+ server << ", ";
+ }
+
+ server << " }";
+}
+
+void outputPins(WebServer &server, WebServer::ConnectionType type, bool addControls = false)
+{
+ P(htmlHead) =
+ "<html>"
+ "<head>"
+ "<title>Arduino Web Server</title>"
+ "<style type=\"text/css\">"
+ "BODY { font-family: sans-serif }"
+ "H1 { font-size: 14pt; text-decoration: underline }"
+ "P { font-size: 10pt; }"
+ "</style>"
+ "</head>"
+ "<body>";
+
+ int i;
+ server.httpSuccess();
+ server.printP(htmlHead);
+
+ if (addControls)
+ server << "<form action='" PREFIX "/form' method='post'>";
+
+ server << "<h1>Digital Pins</h1><p>";
+
+ for (i = 0; i <= 9; ++i)
+ {
+ // ignore the pins we use to talk to the Ethernet chip
+ int val = digitalRead(i);
+ server << "Digital " << i << ": ";
+ if (addControls)
+ {
+ char pinName[4];
+ pinName[0] = 'd';
+ itoa(i, pinName + 1, 10);
+ server.radioButton(pinName, "1", "On", val);
+ server << " ";
+ server.radioButton(pinName, "0", "Off", !val);
+ }
+ else
+ server << (val ? "HIGH" : "LOW");
+
+ server << "<br/>";
+ }
+
+ server << "</p><h1>Analog Pins</h1><p>";
+ for (i = 0; i <= 5; ++i)
+ {
+ int val = analogRead(i);
+ server << "Analog " << i << ": " << val << "<br/>";
+ }
+
+ server << "</p>";
+
+ if (addControls)
+ server << "<input type='submit' value='Submit'/></form>";
+
+ server << "</body></html>";
+}
+
+void formCmd(WebServer &server, WebServer::ConnectionType type, char *url_tail, bool tail_complete)
+{
+ if (type == WebServer::POST)
+ {
+ bool repeat;
+ char name[16], value[16];
+ do
+ {
+ repeat = server.readPOSTparam(name, 16, value, 16);
+ if (name[0] == 'd')
+ {
+ int pin = strtoul(name + 1, NULL, 10);
+ int val = strtoul(value, NULL, 10);
+ digitalWrite(pin, val);
+ }
+ } while (repeat);
+
+ server.httpSeeOther(PREFIX "/form");
+ }
+ else
+ outputPins(server, type, true);
+}
+
+void defaultCmd(WebServer &server, WebServer::ConnectionType type, char *url_tail, bool tail_complete)
+{
+ outputPins(server, type, false);
+}
+
+void setup()
+{
+ // set pins 0-8 for digital input
+ for (int i = 0; i <= 9; ++i)
+ pinMode(i, INPUT);
+ pinMode(9, OUTPUT);
+
+ Ethernet.begin(mac, ip);
+ webserver.begin();
+
+ webserver.setDefaultCommand(&defaultCmd);
+ webserver.addCommand("json", &jsonCmd);
+ webserver.addCommand("form", &formCmd);
+}
+
+void loop()
+{
+ // process incoming connections one at a time forever
+ webserver.processConnection();
+
+ // if you wanted to do other work based on a connecton, it would go here
+}
diff --git a/Webduino/examples/Web_HelloWorld/Web_HelloWorld.ino b/Webduino/examples/Web_HelloWorld/Web_HelloWorld.ino
new file mode 100644
index 0000000..aebf90a
--- /dev/null
+++ b/Webduino/examples/Web_HelloWorld/Web_HelloWorld.ino
@@ -0,0 +1,71 @@
+/* Web_HelloWorld.pde - very simple Webduino example */
+
+#include "SPI.h"
+#include "Ethernet.h"
+#include "WebServer.h"
+
+/* CHANGE THIS TO YOUR OWN UNIQUE VALUE. The MAC number should be
+ * different from any other devices on your network or you'll have
+ * problems receiving packets. */
+static uint8_t mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
+
+
+/* CHANGE THIS TO MATCH YOUR HOST NETWORK. Most home networks are in
+ * the 192.168.0.XXX or 192.168.1.XXX subrange. Pick an address
+ * that's not in use and isn't going to be automatically allocated by
+ * DHCP from your router. */
+static uint8_t ip[] = { 192, 168, 1, 210 };
+
+/* This creates an instance of the webserver. By specifying a prefix
+ * of "", all pages will be at the root of the server. */
+#define PREFIX ""
+WebServer webserver(PREFIX, 80);
+
+/* commands are functions that get called by the webserver framework
+ * they can read any posted data from client, and they output to the
+ * server to send data back to the web browser. */
+void helloCmd(WebServer &server, WebServer::ConnectionType type, char *, bool)
+{
+ /* this line sends the standard "we're all OK" headers back to the
+ browser */
+ server.httpSuccess();
+
+ /* if we're handling a GET or POST, we can output our data here.
+ For a HEAD request, we just stop after outputting headers. */
+ if (type != WebServer::HEAD)
+ {
+ /* this defines some HTML text in read-only memory aka PROGMEM.
+ * This is needed to avoid having the string copied to our limited
+ * amount of RAM. */
+ P(helloMsg) = "<h1>Hello, World!</h1>";
+
+ /* this is a special form of print that outputs from PROGMEM */
+ server.printP(helloMsg);
+ }
+}
+
+void setup()
+{
+ /* initialize the Ethernet adapter */
+ Ethernet.begin(mac, ip);
+
+ /* setup our default command that will be run when the user accesses
+ * the root page on the server */
+ webserver.setDefaultCommand(&helloCmd);
+
+ /* run the same command if you try to load /index.html, a common
+ * default page name */
+ webserver.addCommand("index.html", &helloCmd);
+
+ /* start the webserver */
+ webserver.begin();
+}
+
+void loop()
+{
+ char buff[64];
+ int len = 64;
+
+ /* process incoming connections one at a time forever */
+ webserver.processConnection(buff, &len);
+}
diff --git a/Webduino/examples/Web_Image/Web_Image.ino b/Webduino/examples/Web_Image/Web_Image.ino
new file mode 100644
index 0000000..cafb149
--- /dev/null
+++ b/Webduino/examples/Web_Image/Web_Image.ino
@@ -0,0 +1,117 @@
+/* Web_Image.pde - example sketch for Webduino library */
+/* For webduino version 1.2 */
+
+/* DISCLAIMER -- the Webduino server can only handle one web connection
+ * at a time. Because of this, loading the root page on this sketch may
+ * not correctly show the LED icon if the browser starts requesting that
+ * picture before the page has finished loading.
+ *
+ * This problem should be reduced greatly once the Ethernet library
+ * has been modified to do proper packet buffering. With the library
+ * in Arduino 15, each character is sent in its own TCP/IP packet.
+ * This is very inefficient and means that it takes much longer to
+ * send a web page than it should. When this bug is fixed, the web
+ * server will have sent its last data and closed the connection by
+ * the time the client reads the HTML, so it's ready to handle the
+ * image request.
+ */
+
+#include "SPI.h"
+#include "Ethernet.h"
+#include "WebServer.h"
+
+// CHANGE THIS TO YOUR OWN UNIQUE VALUE
+static uint8_t mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
+static uint8_t ip[] = { 192, 168, 1, 210 };
+
+WebServer webserver("", 80);
+
+/* The default page just returns HTML to show the image */
+void defaultCmd(WebServer &server, WebServer::ConnectionType type, char *url_tail, bool tail_complete)
+{
+ if (type == WebServer::POST)
+ {
+ // ignore POST data
+ server.httpFail();
+ return;
+ }
+
+ /* for a GET or HEAD, send the standard "it's all OK headers" */
+ server.httpSuccess();
+
+ /* we don't output the body for a HEAD request */
+ if (type == WebServer::GET)
+ {
+ /* store the HTML in program memory using the P macro */
+ P(message) =
+ "<html><head><title>Webduino Image Example</title>"
+ "<body>"
+ "<h2>LED Image</h2>"
+ "<img src='led.png' width=256 height=256>"
+ "</body></html>";
+
+ server.printP(message);
+ }
+}
+
+void imageCmd(WebServer &server, WebServer::ConnectionType type, char *url_tail, bool tail_complete)
+{
+ /* this data was taken from a PNG file that was converted to a C data structure
+ * by running it through the directfb-csource application. */
+ P(ledData) = {
+ 0x89, 0x50, 0x4e, 0x47, 0x0d, 0x0a, 0x1a, 0x0a, 0x00, 0x00, 0x00, 0x0d, 0x49, 0x48, 0x44, 0x52,
+ 0x00, 0x00, 0x00, 0x10, 0x00, 0x00, 0x00, 0x10, 0x08, 0x02, 0x00, 0x00, 0x00, 0x90, 0x91, 0x68,
+ 0x36, 0x00, 0x00, 0x00, 0x01, 0x73, 0x52, 0x47, 0x42, 0x00, 0xae, 0xce, 0x1c, 0xe9, 0x00, 0x00,
+ 0x00, 0x04, 0x67, 0x41, 0x4d, 0x41, 0x00, 0x00, 0xb1, 0x8f, 0x0b, 0xfc, 0x61, 0x05, 0x00, 0x00,
+ 0x00, 0x20, 0x63, 0x48, 0x52, 0x4d, 0x00, 0x00, 0x7a, 0x26, 0x00, 0x00, 0x80, 0x84, 0x00, 0x00,
+ 0xfa, 0x00, 0x00, 0x00, 0x80, 0xe8, 0x00, 0x00, 0x75, 0x30, 0x00, 0x00, 0xea, 0x60, 0x00, 0x00,
+ 0x3a, 0x98, 0x00, 0x00, 0x17, 0x70, 0x9c, 0xba, 0x51, 0x3c, 0x00, 0x00, 0x00, 0x18, 0x74, 0x45,
+ 0x58, 0x74, 0x53, 0x6f, 0x66, 0x74, 0x77, 0x61, 0x72, 0x65, 0x00, 0x50, 0x61, 0x69, 0x6e, 0x74,
+ 0x2e, 0x4e, 0x45, 0x54, 0x20, 0x76, 0x33, 0x2e, 0x33, 0x36, 0xa9, 0xe7, 0xe2, 0x25, 0x00, 0x00,
+ 0x00, 0x57, 0x49, 0x44, 0x41, 0x54, 0x38, 0x4f, 0x95, 0x52, 0x5b, 0x0a, 0x00, 0x30, 0x08, 0x6a,
+ 0xf7, 0x3f, 0xf4, 0x1e, 0x14, 0x4d, 0x6a, 0x30, 0x8d, 0x7d, 0x0d, 0x45, 0x2d, 0x87, 0xd9, 0x34,
+ 0x71, 0x36, 0x41, 0x7a, 0x81, 0x76, 0x95, 0xc2, 0xec, 0x3f, 0xc7, 0x8e, 0x83, 0x72, 0x90, 0x43,
+ 0x11, 0x10, 0xc4, 0x12, 0x50, 0xb6, 0xc7, 0xab, 0x96, 0xd0, 0xdb, 0x5b, 0x41, 0x5c, 0x6a, 0x0b,
+ 0xfd, 0x57, 0x28, 0x5b, 0xc2, 0xfd, 0xb2, 0xa1, 0x33, 0x28, 0x45, 0xd0, 0xee, 0x20, 0x5c, 0x9a,
+ 0xaf, 0x93, 0xd6, 0xbc, 0xdb, 0x25, 0x56, 0x61, 0x01, 0x17, 0x12, 0xae, 0x53, 0x3e, 0x66, 0x32,
+ 0xba, 0x00, 0x00, 0x00, 0x00, 0x49, 0x45, 0x4e, 0x44, 0xae, 0x42, 0x60, 0x82
+ };
+
+ if (type == WebServer::POST)
+ {
+ // ignore POST data
+ server.httpFail();
+ return;
+ }
+
+ /* for a GET or HEAD, send the standard "it's all OK headers" but identify our data as a PNG file */
+ server.httpSuccess("image/png");
+
+ /* we don't output the body for a HEAD request */
+ if (type == WebServer::GET)
+ {
+ server.writeP(ledData, sizeof(ledData));
+ }
+}
+
+void setup()
+{
+ // setup the Ehternet library to talk to the Wiznet board
+ Ethernet.begin(mac, ip);
+
+ /* register our default command (activated with the request of
+ * http://x.x.x.x/ */
+ webserver.setDefaultCommand(&defaultCmd);
+
+ /* register our image output command */
+ webserver.addCommand("led.png", &imageCmd);
+
+ /* start the server to wait for connections */
+ webserver.begin();
+}
+
+void loop()
+{
+ // process incoming connections one at a time forever
+ webserver.processConnection();
+}
diff --git a/Webduino/examples/Web_Image/led.png b/Webduino/examples/Web_Image/led.png
new file mode 100644
index 0000000..aa97b62
--- /dev/null
+++ b/Webduino/examples/Web_Image/led.png
Binary files differ
diff --git a/Webduino/examples/Web_Parms/Web_Parms.ino b/Webduino/examples/Web_Parms/Web_Parms.ino
new file mode 100644
index 0000000..4b848a5
--- /dev/null
+++ b/Webduino/examples/Web_Parms/Web_Parms.ino
@@ -0,0 +1,287 @@
+/* Web_Parms_1.pde - very simple Webduino example of parameter passing and parsing */
+
+/*
+ * This is mostly a tool for testing and debugging the library, but can
+ * also be used as an example of coding for it.
+ *
+ * To use it, enter one of the following USLs into your browser.
+ * Replace "host" with the IP address assigned to the Arduino.
+ *
+ * http://host/
+ * http://host/index.html
+ *
+ * These return a "success" HTTP result and display the parameters
+ * (if any) passed to them as a single string, without attempting to
+ * parse them. This is done with a call to defaultCmd.
+ *
+ *
+ * http://host/raw.html
+ *
+ * This is essentially the same as the index.html URL processing,
+ * but is done by calling rawCmd.
+ *
+ *
+ * http://host/parsed.html
+ *
+ * This invokes parsedCmd, which displays the "raw" parameter string,
+ * but also uses the "nexyURLparam" routine to parse out the individual
+ * parameters, and display them.
+ */
+
+
+#define WEBDUINO_FAIL_MESSAGE "<h1>Request Failed</h1>"
+#include "SPI.h" // new include
+#include "avr/pgmspace.h" // new include
+#include "Ethernet.h"
+#include "WebServer.h"
+
+#define VERSION_STRING "0.1"
+
+/* CHANGE THIS TO YOUR OWN UNIQUE VALUE. The MAC number should be
+ * different from any other devices on your network or you'll have
+ * problems receiving packets. */
+static uint8_t mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
+
+
+/* CHANGE THIS TO MATCH YOUR HOST NETWORK. Most home networks are in
+ * the 192.168.0.XXX or 192.168.1.XXX subrange. Pick an address
+ * that's not in use and isn't going to be automatically allocated by
+ * DHCP from your router. */
+static uint8_t ip[] = { 192, 168, 1, 210 };
+
+// ROM-based messages used by the application
+// These are needed to avoid having the strings use up our limited
+// amount of RAM.
+
+P(Page_start) = "<html><head><title>Web_Parms_1 Version " VERSION_STRING "</title></head><body>\n";
+P(Page_end) = "</body></html>";
+P(Get_head) = "<h1>GET from ";
+P(Post_head) = "<h1>POST to ";
+P(Unknown_head) = "<h1>UNKNOWN request for ";
+P(Default_head) = "unidentified URL requested.</h1><br>\n";
+P(Raw_head) = "raw.html requested.</h1><br>\n";
+P(Parsed_head) = "parsed.html requested.</h1><br>\n";
+P(Good_tail_begin) = "URL tail = '";
+P(Bad_tail_begin) = "INCOMPLETE URL tail = '";
+P(Tail_end) = "'<br>\n";
+P(Parsed_tail_begin) = "URL parameters:<br>\n";
+P(Parsed_item_separator) = " = '";
+P(Params_end) = "End of parameters<br>\n";
+P(Post_params_begin) = "Parameters sent by POST:<br>\n";
+P(Line_break) = "<br>\n";
+
+
+
+/* This creates an instance of the webserver. By specifying a prefix
+ * of "", all pages will be at the root of the server. */
+#define PREFIX ""
+WebServer webserver(PREFIX, 80);
+
+
+
+/* commands are functions that get called by the webserver framework
+ * they can read any posted data from client, and they output to the
+ * server to send data back to the web browser. */
+void helloCmd(WebServer &server, WebServer::ConnectionType type, char *url_tail, bool tail_complete)
+{
+ /* this line sends the standard "we're all OK" headers back to the
+ browser */
+ server.httpSuccess();
+
+ /* if we're handling a GET or POST, we can output our data here.
+ For a HEAD request, we just stop after outputting headers. */
+ if (type == WebServer::HEAD)
+ return;
+
+ server.printP(Page_start);
+ switch (type)
+ {
+ case WebServer::GET:
+ server.printP(Get_head);
+ break;
+ case WebServer::POST:
+ server.printP(Post_head);
+ break;
+ default:
+ server.printP(Unknown_head);
+ }
+
+ server.printP(Default_head);
+ server.printP(tail_complete ? Good_tail_begin : Bad_tail_begin);
+ server.print(url_tail);
+ server.printP(Tail_end);
+ server.printP(Page_end);
+
+}
+
+
+void rawCmd(WebServer &server, WebServer::ConnectionType type, char *url_tail, bool tail_complete)
+{
+ /* this line sends the standard "we're all OK" headers back to the
+ browser */
+ server.httpSuccess();
+
+ /* if we're handling a GET or POST, we can output our data here.
+ For a HEAD request, we just stop after outputting headers. */
+ if (type == WebServer::HEAD)
+ return;
+
+ server.printP(Page_start);
+ switch (type)
+ {
+ case WebServer::GET:
+ server.printP(Get_head);
+ break;
+ case WebServer::POST:
+ server.printP(Post_head);
+ break;
+ default:
+ server.printP(Unknown_head);
+ }
+
+ server.printP(Raw_head);
+ server.printP(tail_complete ? Good_tail_begin : Bad_tail_begin);
+ server.print(url_tail);
+ server.printP(Tail_end);
+ server.printP(Page_end);
+
+}
+
+#define NAMELEN 32
+#define VALUELEN 32
+
+void parsedCmd(WebServer &server, WebServer::ConnectionType type, char *url_tail, bool tail_complete)
+{
+ URLPARAM_RESULT rc;
+ char name[NAMELEN];
+ int name_len;
+ char value[VALUELEN];
+ int value_len;
+
+ /* this line sends the standard "we're all OK" headers back to the
+ browser */
+ server.httpSuccess();
+
+ /* if we're handling a GET or POST, we can output our data here.
+ For a HEAD request, we just stop after outputting headers. */
+ if (type == WebServer::HEAD)
+ return;
+
+ server.printP(Page_start);
+ switch (type)
+ {
+ case WebServer::GET:
+ server.printP(Get_head);
+ break;
+ case WebServer::POST:
+ server.printP(Post_head);
+ break;
+ default:
+ server.printP(Unknown_head);
+ }
+
+ server.printP(Parsed_head);
+ server.printP(tail_complete ? Good_tail_begin : Bad_tail_begin);
+ server.print(url_tail);
+ server.printP(Tail_end);
+
+ if (strlen(url_tail))
+ {
+ server.printP(Parsed_tail_begin);
+ while (strlen(url_tail))
+ {
+ rc = server.nextURLparam(&url_tail, name, NAMELEN, value, VALUELEN);
+ if (rc == URLPARAM_EOS)
+ server.printP(Params_end);
+ else
+ {
+ server.print(name);
+ server.printP(Parsed_item_separator);
+ server.print(value);
+ server.printP(Tail_end);
+ }
+ }
+ }
+ if (type == WebServer::POST)
+ {
+ server.printP(Post_params_begin);
+ while (server.readPOSTparam(name, NAMELEN, value, VALUELEN))
+ {
+ server.print(name);
+ server.printP(Parsed_item_separator);
+ server.print(value);
+ server.printP(Tail_end);
+ }
+ }
+ server.printP(Page_end);
+
+}
+
+void my_failCmd(WebServer &server, WebServer::ConnectionType type, char *url_tail, bool tail_complete)
+{
+ /* this line sends the standard "we're all OK" headers back to the
+ browser */
+ server.httpFail();
+
+ /* if we're handling a GET or POST, we can output our data here.
+ For a HEAD request, we just stop after outputting headers. */
+ if (type == WebServer::HEAD)
+ return;
+
+ server.printP(Page_start);
+ switch (type)
+ {
+ case WebServer::GET:
+ server.printP(Get_head);
+ break;
+ case WebServer::POST:
+ server.printP(Post_head);
+ break;
+ default:
+ server.printP(Unknown_head);
+ }
+
+ server.printP(Default_head);
+ server.printP(tail_complete ? Good_tail_begin : Bad_tail_begin);
+ server.print(url_tail);
+ server.printP(Tail_end);
+ server.printP(Page_end);
+
+}
+
+
+
+
+void setup()
+{
+ /* initialize the Ethernet adapter */
+ Ethernet.begin(mac, ip);
+
+ /* setup our default command that will be run when the user accesses
+ * the root page on the server */
+ webserver.setDefaultCommand(&helloCmd);
+
+ /* setup our default command that will be run when the user accesses
+ * a page NOT on the server */
+ webserver.setFailureCommand(&my_failCmd);
+
+ /* run the same command if you try to load /index.html, a common
+ * default page name */
+ webserver.addCommand("index.html", &helloCmd);
+
+ /*This command is called if you try to load /raw.html */
+ webserver.addCommand("raw.html", &rawCmd);
+ webserver.addCommand("parsed.html", &parsedCmd);
+
+ /* start the webserver */
+ webserver.begin();
+}
+
+void loop()
+{
+ char buff[64];
+ int len = 64;
+
+ /* process incoming connections one at a time forever */
+ webserver.processConnection(buff, &len);
+}
generated by cgit v1.2.3 (git 2.39.1) at 2025-10-15 18:02:52 +0000