blob: 3c3aeb8ce173f165ea0c25f3cf7d0f0f747c60f0 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
|
!addplugindir ../altosui/Instdrv/NSIS/Plugins
!addincludedir ../altosui/Instdrv/NSIS/Includes
!include x64.nsh
!include java.nsh
!include refresh-sh.nsh
!define REG_NAME "TeleGPS"
!define PROG_ID_TELEM "altusmetrum.telegps.telem.1"
!define PROG_ID_EEPROM "altusmetrum.telegps.eeprom.1"
!define FAT_NAME "telegps-fat.jar"
!define WIN_APP_ICON "altusmetrum-telegps.ico"
!define WIN_APP_EXE "altusmetrum-telegps.exe"
!define WIN_TELEM_EXE "application-vnd.altusmetrum.telemetry.exe"
!define WIN_EEPROM_EXE "application-vnd.altusmetrum.eeprom.exe"
Name "${REG_NAME} Installer"
; Default install directory
InstallDir "$PROGRAMFILES\AltusMetrum"
; Tell the installer where to re-install a new version
InstallDirRegKey HKLM "Software\${REG_NAME}" "Install_Dir"
LicenseText "GNU General Public License Version 2"
LicenseData "../COPYING"
; Need admin privs for Vista or Win7
RequestExecutionLevel admin
ShowInstDetails Show
ComponentText "${REG_NAME} Software and Driver Installer"
Function .onInit
DetailPrint "Checking host operating system"
${If} ${RunningX64}
DetailPrint "Installer running on 64-bit host"
SetRegView 64
StrCpy $INSTDIR "$PROGRAMFILES64\AltusMetrum"
${DisableX64FSRedirection}
${EndIf}
FunctionEnd
Function un.onInit
DetailPrint "Checking host operating system"
${If} ${RunningX64}
DetailPrint "Installer running on 64-bit host"
SetRegView 64
StrCpy $INSTDIR "$PROGRAMFILES64\AltusMetrum"
${DisableX64FSRedirection}
${EndIf}
FunctionEnd
; Pages to present
Page license
Page components
Page directory
Page instfiles
UninstPage uninstConfirm
UninstPage instfiles
; And the stuff to install
Section "Install Driver" InstDriver
InstDrv::InitDriverSetup /NOUNLOAD {4D36E96D-E325-11CE-BFC1-08002BE10318} AltusMetrumSerial
Pop $0
DetailPrint "InitDriverSetup: $0"
InstDrv::DeleteOemInfFiles /NOUNLOAD
InstDrv::CreateDevice /NOUNLOAD
SetOutPath $INSTDIR
File "../altusmetrum.inf"
File "../altusmetrum.cat"
${DisableX64FSRedirection}
IfFileExists $WINDIR\System32\PnPutil.exe 0 nopnp
${DisableX64FSRedirection}
nsExec::ExecToLog '"$WINDIR\System32\PnPutil.exe" -i -a "$INSTDIR\altusmetrum.inf"'
Goto done
nopnp:
InstDrv::InstallDriver /NOUNLOAD "$INSTDIR\altusmetrum.inf"
done:
SectionEnd
Section "${REG_NAME} Application"
Call DetectJRE
SetOutPath $INSTDIR
File "${FAT_NAME}"
File "altoslib_@ALTOSLIB_VERSION@.jar"
File "altosuilib_@ALTOSUILIB_VERSION@.jar"
File "cmudict04.jar"
File "cmulex.jar"
File "cmu_time_awb.jar"
File "cmutimelex.jar"
File "cmu_us_kal.jar"
File "en_us.jar"
File "freetts.jar"
File "jfreechart.jar"
File "jcommon.jar"
File "*.dll"
File "../icon/${WIN_APP_ICON}"
CreateShortCut "$SMPROGRAMS\${REG_NAME}.lnk" "$INSTDIR\${FAT_NAME}" "" "$INSTDIR\${WIN_APP_ICON}"
SectionEnd
Section "${REG_NAME} Desktop Shortcut"
CreateShortCut "$DESKTOP\${REG_NAME}.lnk" "$INSTDIR\${FAT_NAME}" "" "$INSTDIR\${WIN_APP_ICON}"
SectionEnd
Section "TeleGPS, TeleDongle and TeleBT Firmware"
SetOutPath $INSTDIR
File "../src/telegps-v1.0/telegps-v1.0-${VERSION}.ihx"
File "../src/teledongle-v0.2/teledongle-v0.2-${VERSION}.ihx"
File "../src/telebt-v1.0/telebt-v1.0-${VERSION}.ihx"
SectionEnd
Section "Documentation"
SetOutPath $INSTDIR
File "../doc/telegps.pdf"
File "../doc/altos.pdf"
File "../doc/telemetry.pdf"
SectionEnd
Section "File Associations"
${DisableX64FSRedirection}
SetOutPath $INSTDIR
File "../icon/${WIN_APP_EXE}"
File "../icon/${WIN_TELEM_EXE}"
File "../icon/${WIN_EEPROM_EXE}"
DeleteRegKey HKCR "${PROG_ID_TELEM}"
DeleteRegKey HKCR "${PROG_ID_EEPROM}"
DeleteRegKey HKCR ".eeprom\${PROG_ID_EEPROM}"
DeleteRegValue HKCR ".eeprom\OpenWithProgids" "${PROG_ID_EEPROM}"
DeleteRegKey HKCR ".telem\${PROG_ID_EEPROM}"
DeleteRegValue HKCR ".telem\OpenWithProgids" "${PROG_ID_EEPROM}"
SearchPath $1 "javaw.exe"
; .eeprom elements
WriteRegStr HKCR "${PROG_ID_EEPROM}" "" "Altus Metrum Log File"
WriteRegStr HKCR "${PROG_ID_EEPROM}" "FriendlyTypeName" "Altus Metrum Log File"
WriteRegStr HKCR "${PROG_ID_EEPROM}\CurVer" "" "${PROG_ID_EEPROM}"
WriteRegStr HKCR "${PROG_ID_EEPROM}\DefaultIcon" "" '"$INSTDIR\${WIN_EEPROM_EXE}",-101'
WriteRegExpandStr HKCR "${PROG_ID_EEPROM}\shell\open\command" "" '"$1" -Djava.library.path="$INSTDIR" -jar "$INSTDIR\${FAT_NAME}" "%1"'
WriteRegStr HKCR ".eeprom" "" "${PROG_ID_EEPROM}"
WriteRegStr HKCR ".eeprom" "PerceivedType" "Altus Metrum Log File"
WriteRegStr HKCR ".eeprom" "Content Type" "application/vnd.altusmetrum.eeprom"
WriteRegStr HKCR ".eeprom\OpenWithProgids" "${PROG_ID_EEPROM}" ""
WriteRegStr HKCR ".eeprom\${PROG_ID_EEPROM}" "" "${REG_NAME}"
; .telem elements
WriteRegStr HKCR "${PROG_ID_TELEM}" "" "Altus Metrum Telemetry File"
WriteRegStr HKCR "${PROG_ID_TELEM}" "FriendlyTypeName" "Altus Metrum Telemetry File"
WriteRegStr HKCR "${PROG_ID_TELEM}\CurVer" "" "${PROG_ID_TELEM}"
WriteRegStr HKCR "${PROG_ID_TELEM}\DefaultIcon" "" '"$INSTDIR\${WIN_TELEM_EXE}",-101'
WriteRegExpandStr HKCR "${PROG_ID_TELEM}\shell\open\command" "" '"$1" -Djava.library.path="$INSTDIR" -jar "$INSTDIR\${FAT_NAME}" "%1"'
WriteRegStr HKCR ".telem" "" "${PROG_ID_TELEM}"
WriteRegStr HKCR ".telem" "PerceivedType" "Altus Metrum Telemetry File"
WriteRegStr HKCR ".telem" "Content Type" "application/vnd.altusmetrum.telemetry"
WriteRegStr HKCR ".telem\OpenWithProgids" "${PROG_ID_TELEM}" ""
WriteRegStr HKCR ".telem\${PROG_ID_TELEM}" "" "${REG_NAME}"
Call RefreshShellIcons
SectionEnd
Section "Uninstaller"
; Deal with the uninstaller
${DisableX64FSRedirection}
SetOutPath $INSTDIR
; Write the install path to the registry
WriteRegStr HKLM "SOFTWARE\${REG_NAME}" "Install_Dir" "$INSTDIR"
; Write the uninstall keys for windows
WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\${REG_NAME}" "DisplayName" "${REG_NAME}"
WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\${REG_NAME}" "UninstallString" '"$INSTDIR\uninstall-${REG_NAME}.exe"'
WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\${REG_NAME}" "NoModify" "1"
WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\${REG_NAME}" "NoRepair" "1"
WriteUninstaller "uninstall-${REG_NAME}.exe"
SectionEnd
Section "Uninstall"
${DisableX64FSRedirection}
DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\${REG_NAME}"
DeleteRegKey HKLM "SOFTWARE\${REG_NAME}"
DetailPrint "Delete uninstall reg entries"
DeleteRegKey HKCR "${PROG_ID_EEPROM}"
DeleteRegKey HKCR "${PROG_ID_TELEM}"
DeleteRegKey HKCR ".eeprom\${PROG_ID_EEPROM}"
DeleteRegValue HKCR ".eeprom\OpenWithProgids" "${PROG_ID_EEPROM}"
DeleteRegKey HKCR ".telem\${PROG_ID_TELEM}"
DeleteRegValue HKCR ".telem\OpenWithProgids" "${PROG_ID_TELEM}"
DetailPrint "Delete file association reg entries"
Delete "$INSTDIR\${FAT_NAME}"
Delete "$INSTDIR\uninstall-${REG_NAME}.exe"
Delete "$INSTDIR\${WIN_APP_ICON}"
Delete "$INSTDIR\${WIN_APP_EXE}"
; Remove shortcuts, if any
Delete "$SMPROGRAMS\${REG_NAME}.lnk"
Delete "$DESKTOP\${REG_NAME}.lnk"
Call un.RefreshShellIcons
SectionEnd
|
