1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
|
/*
* Copyright © 2012 Keith Packard <keithp@keithp.com>
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful, but
* WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* General Public License for more details.
*
* You should have received a copy of the GNU General Public License along
* with this program; if not, write to the Free Software Foundation, Inc.,
* 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
*/
MEMORY {
rom (rx) : ORIGIN = 0x08001000, LENGTH = 20K
flash(rx) : ORIGIN = 0x08006000, LENGTH = 8K
ram (!w) : ORIGIN = 0x20000000, LENGTH = 6k - 512
stack (!w) : ORIGIN = 0x20000000 + 6k - 512, LENGTH = 512
}
INCLUDE registers.ld
EXTERN (stm_interrupt_vector)
SECTIONS {
/*
* Rom contents
*/
.interrupt ORIGIN(ram) : AT (ORIGIN(rom)) {
__interrupt_start__ = .;
__interrupt_rom__ = ORIGIN(rom);
*(.interrupt) /* Interrupt vectors */
__interrupt_end__ = .;
} > ram
.text ORIGIN(rom) + 0x100 : {
__text_start__ = .;
/* Ick. What I want is to specify the
* addresses of some global constants so
* that I can find them across versions
* of the application. I can't figure out
* how to make gnu ld do that, so instead
* we just load the two files that include
* these defines in the right order here and
* expect things to 'just work'. Don't change
* the contents of those files, ok?
*/
ao_romconfig.o(.romconfig*)
ao_product.o(.romconfig*)
*(.text*) /* Executable code */
} > rom
.ARM.exidx : {
*(.ARM.exidx* .gnu.linkonce.armexidx.*)
} > rom
.rodata : {
*(.rodata*) /* Constants */
} > rom
__text_end__ = .;
/* Boot data which must live at the start of ram so that
* the application and bootloader share the same addresses.
* This must be all uninitialized data
*/
.boot (NOLOAD) : {
__boot_start__ = .;
*(.boot)
. = ALIGN(4);
__boot_end__ = .;
} >ram
/* Functions placed in RAM (required for flashing)
*
* Align to 8 bytes as that's what the ARM likes text
* segment alignments to be, and if we don't, then
* we end up with a mismatch between the location in
* ROM and the desired location in RAM. I don't
* entirely understand this, but at least this appears
* to work...
*/
.textram BLOCK(8): {
__data_start__ = .;
*(.ramtext)
} >ram AT>rom
/* Data -- relocated to RAM, but written to ROM,
* also aligned to 8 bytes to agree with textram
*/
.data BLOCK(8): {
*(.data) /* initialized data */
__data_end__ = .;
} >ram AT>rom
.bss : {
__bss_start__ = .;
*(.bss)
*(COMMON)
. = ALIGN(4);
__bss_end__ = .;
} >ram
PROVIDE(end = .);
PROVIDE(__flash__ = ORIGIN(flash));
PROVIDE(__flash_end__ = ORIGIN(flash) + LENGTH(flash));
PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
}
ENTRY(start);
|
