From 9279fd42793123784ce83ca151df6f4630487722 Mon Sep 17 00:00:00 2001
From: Keith Packard <keithp@keithp.com>
Date: Fri, 16 Mar 2012 20:21:09 -0700
Subject: Add STM platform and stm-bringup demo program

The stm-bringup doesn't run altos, it just initializes the device and
writes stuff over a serial port. Works on the STM32L Discovery board
at least, should do stuff on other boards too.

Signed-off-by: Keith Packard <keithp@keithp.com>
---
 src/stm/altos.ld | 72 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 src/stm/altos.ld

(limited to 'src/stm/altos.ld')

diff --git a/src/stm/altos.ld b/src/stm/altos.ld
new file mode 100644
index 00000000..4e955666
--- /dev/null
+++ b/src/stm/altos.ld
@@ -0,0 +1,72 @@
+/*
+ * Copyright © 2012 Keith Packard <keithp@keithp.com>
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; version 2 of the License.
+ *
+ * This program is distributed in the hope that it will be useful, but
+ * WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License along
+ * with this program; if not, write to the Free Software Foundation, Inc.,
+ * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
+ */
+
+MEMORY {
+	rom (rx) : ORIGIN = 0x08000000, LENGTH = 128K
+	ram (!w) : ORIGIN = 0x20000000, LENGTH = 16K
+}
+
+INCLUDE registers.ld
+
+EXTERN (stm_interrupt_vector)
+C_STACK_SIZE = 512;
+
+SECTIONS {
+	. = ORIGIN(rom);
+
+	/*
+	 * Rom contents
+	 */
+
+	__text_start__ = .;
+
+	.text : {
+		*(.interrupt)	/* Interrupt vectors */
+		*(.text)	/* Executable code */
+		*(.rodata)	/* Constants */
+	} > rom
+
+	.ARM.exidx : {
+		*(.ARM.exidx* .gnu.linkonce.armexidx.*)
+		__text_end__ = .;
+	} > rom
+
+	. = ORIGIN(ram);
+	__data_start__ = .;
+
+	/* Data -- relocated to RAM, but written to ROM
+	 */
+	.data : AT (ADDR(.ARM.exidx) + SIZEOF (.ARM.exidx)) {
+		*(.data)	/* initialized data */
+		__data_end__ = .;
+		__bss_start__ = .;
+	} >ram
+
+	.bss : {
+		*(.bss)
+		*(COMMON)
+		__bss_end__ = .;
+	} >ram
+
+	PROVIDE(__stack__ = . + C_STACK_SIZE);
+	PROVIDE(end = .);
+
+}
+
+ENTRY(start);
+
+
-- 
cgit v1.2.3